final: prev:
let
  inherit (final) lib callPackage;

  alpine-patches = callPackage ./pkgs/alpine-patches.nix { };
  gentoo-patches = callPackage ./pkgs/gentoo-patches.nix { };
in {
  keyutils = prev.keyutils.overrideAttrs (base: {
    buildFlags = base.buildFlags or [ ]
      ++ lib.optional final.keyutils.stdenv.cc.bintools.isLLVM
        "LDFLAGS=-Wl,--undefined-version";
  });

  cpp-utilities = prev.cpp-utilities.overrideAttrs (base: {
    buildInputs = [ final.boost ];
  });

  diffutils = prev.diffutils.overrideAttrs (_: {
    # getopt tests fail
    doCheck = false;
  });

  jemalloc = prev.jemalloc.override {
    stdenv = final.gccStdenv;
  };

  perl538Packages = prev.perl538Packages // (with prev.perl538Packages; {
    StringShellQuote = StringShellQuote.overrideAttrs (_: {
      doCheck = false;
    });
  });

  python312 = prev.python312.override {
  };

  time = prev.time.overrideAttrs (base: {
    patches = base.patches or [ ]
      ++ lib.optional final.time.stdenv.cc.isClang
        "${gentoo-patches}/sys-process/time/files/time-1.9-implicit-func-decl-clang.patch";
  });
}