55 lines
1.7 KiB
Nix
55 lines
1.7 KiB
Nix
|
final: prev:
|
||
|
|
let
|
||
|
|
inherit (final) lib callPackage;
|
||
|
|
|
||
|
|
alpine-patches = callPackage ./pkgs/alpine-patches.nix { };
|
||
|
|
gentoo-patches = callPackage ./pkgs/gentoo-patches.nix { };
|
||
|
|
in {
|
||
|
|
keyutils = prev.keyutils.overrideAttrs (base: {
|
||
|
|
buildFlags = base.buildFlags or [ ]
|
||
|
|
++ lib.optional final.keyutils.stdenv.cc.bintools.isLLVM
|
||
|
|
"LDFLAGS=-Wl,--undefined-version";
|
||
|
|
});
|
||
|
|
|
||
|
|
cpp-utilities = prev.cpp-utilities.overrideAttrs (base: {
|
||
|
|
buildInputs = [ final.boost ];
|
||
|
|
});
|
||
|
|
|
||
|
|
diffutils = prev.diffutils.overrideAttrs (_: {
|
||
|
|
# getopt tests fail
|
||
|
|
doCheck = false;
|
||
|
|
});
|
||
|
|
|
||
|
|
dpkg = prev.dpkg.overrideAttrs (_: {
|
||
|
|
postPatch = ''
|
||
|
|
patchShebangs .
|
||
|
|
|
||
|
|
substituteInPlace lib/dpkg/dpkg.h \
|
||
|
|
--replace '"dpkg-deb"' \"$out/bin/dpkg-deb\" \
|
||
|
|
--replace '"dpkg-split"' \"$out/bin/dpkg-split\" \
|
||
|
|
--replace '"dpkg-query"' \"$out/bin/dpkg-query\" \
|
||
|
|
--replace '"dpkg-divert"' \"$out/bin/dpkg-divert\" \
|
||
|
|
--replace '"dpkg-statoverride"' \"$out/bin/dpkg-statoverride\" \
|
||
|
|
--replace '"dpkg-trigger"' \"$out/bin/dpkg-trigger\" \
|
||
|
|
--replace '"dpkg"' \"$out/bin/dpkg\" \
|
||
|
|
--replace '"debsig-verify"' \"$out/bin/debsig-verify\" \
|
||
|
|
--replace '"rm"' \"${final.coreutils}/bin/rm\" \
|
||
|
|
--replace '"cat"' \"${final.coreutils}/bin/cat\" \
|
||
|
|
--replace '"diff"' \"${final.diffutils}/bin/diff\" \
|
||
|
|
--replace '"ldconfig"' \"${final.coreutils}/bin/true\"
|
||
|
|
'';
|
||
|
|
}).override {
|
||
|
|
glibc = null;
|
||
|
|
};
|
||
|
|
|
||
|
|
jemalloc = prev.jemalloc.override {
|
||
|
|
stdenv = final.gccStdenv;
|
||
|
|
};
|
||
|
|
|
||
|
|
time = prev.time.overrideAttrs (base: {
|
||
|
|
patches = base.patches or [ ]
|
||
|
|
++ lib.optional final.time.stdenv.cc.isClang
|
||
|
|
"${gentoo-patches}/sys-process/time/files/time-1.9-implicit-func-decl-clang.patch";
|
||
|
|
});
|
||
|
|
}
|