moderation/flake.nix

{
  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
  outputs = { self, nixpkgs, ... }: let
    inherit (nixpkgs) lib;
    eachSystem = lib.genAttrs [ "x86_64-linux" "aarch64-linux" ];
  in {
    nixosModules = {
      default = import ./module.nix;
      florp = args: {
        services.akkoma.moderation = import ./florp.nix args;
      };
    };

    nixosConfigurations = eachSystem (system: lib.nixosSystem {
      inherit system;
      modules = [ {
        system.stateVersion = "24.11";
        fileSystems."/".device = "nodev";
        boot.loader.grub.enable = false;
        services.akkoma.enable = true;
        services.akkoma.config.":pleroma".":instance" = {
          name = "test";
          description = "test";
          email = "test@test.test";
        };
      } ] ++ (with self.nixosModules; [ default florp ]);
    });

    checks = eachSystem (system: {
      default = self.nixosConfigurations.${system}.config.system.build.toplevel;
    });
  };
}